qcocoainputcontext.mm

Go to the documentation of this file.

// Copyright (C) 2016 The Qt Company Ltd.
// SPDX-License-Identifier: LicenseRef-Qt-Commercial OR LGPL-3.0-only OR GPL-2.0-only OR GPL-3.0-only
 
#include <AppKit/AppKit.h>
 
#include "qnsview.h"
#include "qcocoainputcontext.h"
#include "qcocoanativeinterface.h"
#include "qcocoawindow.h"
#include "qcocoahelpers.h"
 
#include <Carbon/Carbon.h>
 
#include <QtCore/QRect>
#include <QtGui/QGuiApplication>
#include <QtGui/QWindow>
 
QT_BEGIN_NAMESPACE
 
QCocoaInputContext::QCocoaInputContext()
    : QPlatformInputContext()
    , m_focusWindow(QGuiApplication::focusWindow())
{
    m_inputSourceObserver = QMacNotificationObserver(nil,
        NSTextInputContextKeyboardSelectionDidChangeNotification, [&]() {
        qCDebug(lcQpaInputMethods) << "Text input source changed";
        updateLocale();
    });
 
    updateLocale();
}
 
QCocoaInputContext::~QCocoaInputContext()
{
}
 
void QCocoaInputContext::commit()
{
    qCDebug(lcQpaInputMethods) << "Committing composition";
 
    if (!m_focusWindow)
        return;
 
    auto *platformWindow = m_focusWindow->handle();
    if (!platformWindow)
        return;
 
    auto *cocoaWindow = static_cast<QCocoaWindow *>(platformWindow);
    QNSView *view = qnsview_cast(cocoaWindow->view());
    if (!view)
        return;
 
    [view unmarkText];
 
    [view.inputContext discardMarkedText];
    if (view.inputContext != NSTextInputContext.currentInputContext) {
        // discardMarkedText will activate the TSM document of the given input context,
        // which may not match the current input context. To ensure the current input
        // context is not left in an inconsistent state with a deactivated document
        // we need to manually activate it here.
        [NSTextInputContext.currentInputContext activate];
    }
}
 
 
void QCocoaInputContext::reset()
{
    qCDebug(lcQpaInputMethods) << "Resetting input method";
 
    if (!m_focusWindow)
        return;
 
    QCocoaWindow *window = static_cast<QCocoaWindow *>(m_focusWindow->handle());
    QNSView *view = qnsview_cast(window->view());
    if (!view)
        return;
 
    if (NSTextInputContext *ctxt = [NSTextInputContext currentInputContext]) {
        [ctxt discardMarkedText];
        [view unmarkText];
    }
}
 
void QCocoaInputContext::setFocusObject(QObject *focusObject)
{
    qCDebug(lcQpaInputMethods) << "Focus object changed to" << focusObject;
 
    if (m_focusWindow == QGuiApplication::focusWindow()) {
        if (!m_focusWindow)
            return;
 
        QCocoaWindow *window = static_cast<QCocoaWindow *>(m_focusWindow->handle());
        if (!window)
            return;
        QNSView *view = qnsview_cast(window->view());
        if (!view)
            return;
 
        if (NSTextInputContext *ctxt = [NSTextInputContext currentInputContext]) {
            [ctxt discardMarkedText];
            [view cancelComposingText];
        }
    } else {
        m_focusWindow = QGuiApplication::focusWindow();
    }
}
 
void QCocoaInputContext::updateLocale()
{
    QCFType<TISInputSourceRef> source = TISCopyCurrentKeyboardInputSource();
    NSArray *languages = static_cast<NSArray*>(TISGetInputSourceProperty(source,
                                               kTISPropertyInputSourceLanguages));
 
    qCDebug(lcQpaInputMethods) << "Input source supports" << languages;
    if (!languages.count)
        return;
 
    QString language = QString::fromNSString(languages.firstObject);
    QLocale locale(language);
 
    bool localeUpdated = m_locale != locale;
    static bool firstUpdate = true;
 
    m_locale = locale;
 
    if (localeUpdated && !firstUpdate) {
        qCDebug(lcQpaInputMethods) << "Reporting new locale" << locale;
        emitLocaleChanged();
    }
 
    firstUpdate = false;
}
 
QT_END_NAMESPACE